Python Developers, ever wanted an easier way to create or activate multiple different virtual environments? This is something that has plagued me for sometime.
One option that has been developed and works ok is Anaconda, but that does not work well with internal Pip packages or install packages from source.
An alternative I came across a couple of months ago in a tutorial on setting up Django written by DigitalOcean, has you setup a test repo and a production repo and create an alias workon that takes a parameter for activating the correct virtual environment.
Why not make workon able to make a venv?
To make coding this easier, I put a file named workon.bat in a directory that I have added to my PATH variable (in my case, c:\bin - a place where I store similar utilities), this makes typing workon on the command line call this script.
At a high level, the script should:
accept an argument
if none is provided, print useage information and exit
else, store that name
Check if there is a folder locally by that name
if so, call %1\scripts\activate to activate the venv
Check if there is one in a “global” folder (which I made a config variable at the top of the script)
if so, call %_envs_root%\%1\scripts\activate to activate it.
If it does not exist in either location, then we need to create it.
I’ve opted to have it prompt (Y/n) to ask for local vs global, aftwards it makes the venv, and activates it and exits.
@ECHO OFF
REM default location for global venvs
set _envs_root=C:\venvs
GOTO :MAIN
:USAGE
echo Usage:
echo %0 {env}
echo Will search for env in cwd (%cd%)
echo or at root (%_envs_root%)
exit /B -1
:ACTIVATE
REM activate based on parameter passed in
call %1\scripts\activate
EXIT /B %errorlevel%
:MAIN
REM if no paremeter, call usage which will exit
IF "%1"=="" GOTO :USAGE
REM else, search for the env
:SEARCH
IF EXIST "%1" (
REM activate local
CALL :ACTIVATE %1
EXIT /B %errorlevel%
)
IF EXIST "%_envs_root%\%1" (
REM activate global
CALL :ACTIVATE %_envs_root%\%1
EXIT /B %errorlevel%
)
REM not found
ECHO Venv "%1" not found.
REM clear the variable before prompting whether to create locally or in the global deposit
set _local=
set /p _local="Create locally? ("no" will create in %_envs_root%) [Y/n]: "
REM set delayed expansion to allow for getting the cwd in the if statement.
SETLOCAL EnableDelayedExpansion
REM accept 'N' or 'n' via case insensitive match, only check first letter
IF /I "%_local:~0,1%"=="n" (
echo Creating in venvs root (%_envs_root%)
PUSHD %_envs_root%
REM store our current location using delayed expansion
set _root=!cd!
call python -m venv %1
POPD
) ELSE (
echo Creating locally (!cd!)
REM store our current location using delayed expansion
set _root=!cd!
call python -m venv %1
)
REM end the local scope, and copy _root out of it
ENDLOCAL & set _root=%_root%
CALL :ACTIVATE %_root%\%1
EXIT /B %errorlevel%
(Download: Click Here)